Summary

Author: Lukas M. Süss aka mechadense
Date: 2022-04-23
License: CC-BY-SA-4.0

Compilation of data on
superlubric friction and its scaling.

(wiki-TODO: add the gnuplot sourcecode & migrate notes over from sci-nanotech)

Additional notes on sci-nanotech forum:
https://sci-nanotech.com/index.php?thread/43-a-closer-look-at-friction-in-cog-gear-style-stiff-nanomachinery/

Sources for the graphs data

– [FiMM] 2017 – Evaluating the Friction of Rotary Joints in Molecular Machines … via rcs, via arxiv
– [VD] 2016 – Eric Drexler Blog: Phonon drag in sleeve bearings can be orders of magnitude smaller than viscous drag in liquids
– [N] 1992 – Nanosystems: Molecular Machinery, Manufacturing, and Computation … https://nanosyste.ms/

Licensing

Template:Self

Gnuplot source

Install gnuplot, store it in text-file
(I had frictionplot-v4.txt) and call it with:
$gnuplot -persist frictionplot-v4.txt

The code could use cleanup,
but I'll never put it online at this rate
so here it is as-is.

The code

# Nanosystems page 293
# conservative limit for drag losses in diamondoid & nanotube bearings


# TODO
# Resolve the mysteries:
# (1) why is the blue plotine (nanotubes concrete and supposedly pretty accurate) so high up while
# the maincolor plot lines (bearings rough and supposed to be conservative) so far down?? 
# -- recheck numbers once more ... 
# (2) why is the planar case so much further down than the backwards-computed bearing case? that's even worse ...
# Have I found an error in Nanosystems? Some overlooked damping mechanism ?
# what are the limits to which these approximations hold roughly? That is
# where does the modeld break down and the plotlines don't hold anymore?

set encoding utf8

# "diamondoid" is maybe too geberal friction in other gemstones may differ a bit
# "strained shell" would exclude the flat case which is also present
# "dynamic drag frictive power-dissipation losses in nanotube and diamondoid bearings " -- too long
set title "friction in nanotube and diamond bearings at 300K" # (normalized to per-bearing-area) (partly conservative upper bounds)
set xlabel "speed in m/s"
#set ylabel "power loss in W"
set ylabel "power loss per bearing area in W/m^2"


# +++++++++++++++++++++++++++
# From Table 1 (page 6):
rnanotube = 0.6 * 10**-9 # m
lnanotube = 5 * 10**-9 # m
Ananotube = lnanotube * 2 * pi * rnanotube
# limited comparability issue: 
# this bearing is smaller and out of nanotubes
# +++++++++++++++++++++++++++


# Nanosystems page 174 – more general for planar case – page 176 ...
# Nanosystems page 293 - bearing case 
# +++++++++++++++++++++++++++ Eq (10.27)
# Values from book: 
# Nanosystems: Molecular machinery, manufacturing, and Computation
# Page 293 Chapter: 10.4.6. Mechanisms of energy dissipoation - f. Summary.
ksbear = 1000 # N/m
reff = 2*10**-9 # m
l = 2*10**-9 # m
R = 10 # unitless
dkapka1 = 0.4 # (N/m)/(N/m) # dominant factor is band-stiffness scattering
dkapka2 = 0.003 # (N/m)/(N/m) # dominant factor is shear-reflection-drag scattering (requires special bearing design)
Abearing = l * 2 * pi * reff
# side-note to avert confusion: 
# "bands" here refer to gemetric "alignement bands" not "conduction bands"
#++++++++++++++++++++++++++++
# drag losses per bearing area -- values for the planar case - Eq (7.35) (10.23)
epsilon = 2 * 10**8 # J/m^3 -- phonon energy density
deltaTtrans = 10**-3 # page 174 bottom
dkapka0 = 0.1
vs = 10**4 # m/s
# +++++++++++++++++++++++++++
# +++++++++++++++++++++++++++
# Following values from paper: "Evaluating the Friction of Rotary Joints in Molecular Machines" (2017)
# krd = 2.9 +- 1.5 * 10^-33 (kg m^2)/s -- we'll use the upper limit as worst case -- 4.2 Nanotube Drag - fluctuation dissipation method
# krd' = 3.4 +- 0.8 * 10^-33 (kg m^2)/s -- based on simulations at higher speeds, above 25 GHz - moleculad dynamics simulation

# mid values - fluctu-sim
krd = 2.9 * 10**-33 # (kg m^2)/s -- or in more comprehensible units -- Nm / (1/s)
# mid value - moldyn-sim
krd2 = 3.4 * 10**-33 # (kg m^2)/s -- or in more comprehensible units -- Nm / (1/s)

krd_top = 4.4 * 10**-33 # (kg m^2)/s -- or in more comprehensible units -- Nm / (1/s)
krd_bot = 1.4 * 10**-33 # (kg m^2)/s -- or in more comprehensible units -- Nm / (1/s)
krd2_top = 4.2 * 10**-33 # (kg m^2)/s -- or in more comprehensible units -- Nm / (1/s)
krd2_bot = 2.6 * 10**-33 # (kg m^2)/s -- or in more comprehensible units -- Nm / (1/s)
# biggest (common) upper bound
krd_max = 4.4 * 10**-33 # (kg m^2)/s -- or in more comprehensible units -- Nm / (1/s)

f = 1.1 # just to shift the errorbar to the right a bit
fluctuspeed = 30 # m/s
moldynspeed = 94 # m/s
fluctu_error_top = 1/Ananotube * krd_top * (fluctuspeed*f)**2 / rnanotube**2
fluctu_error_bot = 1/Ananotube * krd_bot * (fluctuspeed*f)**2 / rnanotube**2
moldyn_error_top = 1/Ananotube * krd2_top * (moldynspeed*f)**2 / rnanotube**2
moldyn_error_bot = 1/Ananotube * krd2_bot * (moldynspeed*f)**2 / rnanotube**2




# +++++++++++++++++++++++++++
# For comparison sphere rotating in a liquid
# https://web.archive.org/web/20160305212101/http://e-drexler.com/p/04/03/0322drags.html
rtestsphere = 2*10**-9 # m
Atestsphere = 4 * pi * rtestsphere**2


maincolor = "red" # "orange"
# maincolor = rgbcolor "#002500" # ??


#set terminal epslatex size 9cm,7cm color colortext standalone header \
#   "\\newcommand{\\ft}[0]{\\footnotesize}"
# set label 2 'proposed speeds' at 0.002,1e5 rotate by 0 center tc ls 1 # textcolor rgb maincolor
#set label '\shortstack{first line\\second line}'

#set label "proposed speeds" at 0.0045,1e5 center textcolor rgb maincolor # lt 4
set label "proposed speeds" at 0.01,1e5 center textcolor rgb maincolor # lt 4
set label "fluctu-sim" at 20,10 rotate by 90 center textcolor rgb "blue" #43
set label "moldyn-sim" at 65,10 rotate by 90 center textcolor rgb "magenta" #140

set label "centrifugal limit" at 2000,1e3 rotate by 90 center textcolor rgb "brown"
set label "example speeds" at 1,1e8 rotate by 0 center textcolor rgb maincolor
#set label "$\\sin(x+\\pi)$" at 1,1e10 rotate by 0 center textcolor rgb maincolor
#set label "1/Abearing * (2.0e-33 + 3.5e-33 * dkapka * R**2) * ksbear**1.7 / (l*reff)**0.7 * v**2" at 0.0002,2e12 rotate by 0 left textcolor "red" font ",6"

set label "[N0] (eq:7.35) P_{drag} = A_{bearing} * 0.85 * (ϵ=2e+8J/m^3) * (T_{trans}=1e-3*1/3) * (Δk_a/k_a=0.1) * (R=10)^2 * v^2 / (v_s=1e+4m/s) " at 0.00015,3e12 rotate by 0 left textcolor "orange" font ",6"
set label "[N1],[N2] (eq:10.27) P_{drag} = (2.0e-33 + 3.5e-33 * (Δk_a/k_a=[0.4;0.003]) * (R=10)^2) * (k_{s,bear}=1000N/m)^{1.7} / (l*r_{eff})^{0.7} * v^2" at 0.00015,3e11 rotate by 0 left textcolor "red" font ",6"
set label "[FiMM1] (4.2) P_{drag} = (k_{rd} = 2.9±1.5e-33 Nm/(1/s)) * v^2 / r^2" at 0.00015,3e+10 rotate by 0 left textcolor "blue" font ",6"
set label "[FiMM2] (4.2) P_{drag} = (k_{rd} = 3.4±0.8e-33 Nm/(1/s)) * v^2 / r^2" at 0.00015,3e+9 rotate by 0 left textcolor "magenta" font ",6"
set label "[VD] P_{viscous-drag} = 8π * (η=1e-3Pa*s) * (r=2nm) * v^2" at 0.00015,3e8 rotate by 0 left textcolor "black" font ",6"
set label "Chart by Lukas M. Süss aka mechadense" at 0.00015,3e7 rotate by 0 left textcolor "web-green" font ",6"
set label "CC-BY-4.0" at 0.00015,3e6 rotate by 0 left textcolor "web-green" font ",6"

#set xtics rotate
set xtics rotate by 45 right
set ytics (10**-16,10**-15,10**-14,10**-13,  10**-6,10**-5,10**-4,10**-3,10**-2,10**-1,10**0,10**1,10**2,10**3,10**4,10**5,10**6,10**7,10**8,10**9,10**10,10**11,10**12)

# legend
set key bottom right
set key font ",5"
set key spacing 1

set grid x
set grid y
#set format x "%.0s 10^{%S}"
#set format y '%.0s*10^%S'
set format y "10^{%L}"
#set format y "%.0s 10^{%S}"
#set format y "%e"


set logscale x 10
set logscale y 10
set xrange [10**-4 : 10**4] # range from 1um/s to 1km/s
# set ytics 1e-3, 10, 1
# set format y "10**{%L}"

numchambers = 10**18 # from Nanosystems Table 14.1 page 422
numbearingsperchamber = 100 # delibertely high 
numbearings = numchambers * numbearingsperchamber






# simulation speeds
# 25e9Hz * 0.6e-9m * 2pi = 94.24777960769379 m/s
# 8e9Hz  * 0.6e-9m * 2pi = 30.159289474462014 m/s

# Vertical lines
set arrow from 3000,graph(0,0.25) to 3000,graph(0,1) nohead lt rgb "brown" # fundamental unsupported rotatig ring speed limit

# Vertical lines - (simulation speeds)
set arrow from fluctuspeed,graph(0,0.25) to fluctuspeed,graph(0,0.8) nohead lt rgb "blue" # 30m/s is used speed in nanotube fluctu-simulation (new fast fluctuations based one)
set arrow from moldynspeed,graph(0,0.25) to moldynspeed,graph(0,0.85) nohead lt rgb "magenta" # 94m/s is used speed in nanotube moldyn-simulation (old slow explicit simulation)
# Vertical lines - (somulation error bars)
set arrow from (fluctuspeed*f),fluctu_error_bot to (fluctuspeed*f),fluctu_error_top nohead lt rgb "blue" front # 30m/s
set arrow from (moldynspeed*f),moldyn_error_bot to (moldynspeed*f),moldyn_error_top nohead lt rgb "magenta" front # 94m/s

# Vertical lines - (theory - Nanosystems)
set arrow from 0.005,graph(0,0) to 0.005,graph(0,0.5) nohead lt rgb maincolor # proposed speeds for on-chip diamondoid nanofactories
set arrow from 0.004,graph(0,0) to 0.004,graph(0,0.5) nohead lt rgb maincolor # proposed speeds for on-chip diamondoid nanofactories
set arrow from 1.000,graph(0,0.25) to 1.000,graph(0,0.65) nohead lt rgb maincolor # example speeds
set arrow from 0.001,graph(0,0) to 0.001,graph(0,0.5) nohead lt rgb maincolor dashtype 2 # proposed low end speeds for on-chip diamondoid nanofactories
set arrow from 10.00,graph(0,0.25) to 10.00,graph(0,0.8) nohead lt rgb maincolor dashtype 2 # proposed top speeds for on-chip diamondoid nanofactories

# 0.005m/s as proposed speed is taken from Nanosystems which mentions it tree times:
# Nanosystems page 26 "Most mechanical motions considered in this volume, however, have speeds between 0.001 and 10 m/s."
# Nanosystems page 387 "... v = 0.005m/s ... moderately greater than the typical value assumed in Chapter 8. ..."
# Nanosystems page 395 "Adopting a 4 nm spacing, a mechanism that delivers 10**6 moieties per second requires a 0.004 m/s belt speed; this speed is assumed throughout this section."

# Nanosystems 14.4.8 dissipation is dominated by moietal operations => 13.3.7 


# ----------------------------------------------------------------
# Note the planar case only includes here dominant band-stiffness scattering term for now
# going down with dkapka0 would require adding shear reflection drag too
plot \
  0.85 * epsilon * deltaTtrans*1/3 * dkapka0 * R**2 * x**2 / vs lt rgb "orange" title "sliding on flat surface – band-stiffness-scattering phonen-drag – upper bound from theory [N0]", \
  1/Abearing * (2.0*10**-33 + 3.5*10**-33 * dkapka1 * R**2) * ksbear**1.7 / (l*reff)**0.7 * x**2 lt rgb maincolor title "4nm Ø bearings – l=r_{eff}=2nm – band-stiffness-scattering dominant – upper bound from theory [N1]", \
  1/Abearing * (2.0*10**-33 + 3.5*10**-33 * dkapka2 * R**2) * ksbear**1.7 / (l*reff)**0.7 * x**2 lt rgb maincolor dashtype 3 title "4nm Ø bearings – l=r_{eff}=2nm – shear-reflection-drag dominant – upper bound from theory [N2]", \
  1/Ananotube * krd * x**2 / rnanotube**2 lt rgb "blue"  title "1.2nm Ø – l=5nm – nested nanotube bearings – fluctuation-dissipation simulations – [FiMM1]" , \
  1/Ananotube * krd2 * x**2 / rnanotube**2 lt rgb "magenta" title "1.2nm Ø – l=5nm – nested nanotube bearings – molecular-dynamics simulations – [FiMM2]" , \
  1/Atestsphere * 5.0*10**-11 * x**2 lt rgb "black" title "4nm Ø spheres spinning in water – viscous drag – theory [VD]"

  # 1/Ananotube * krd_top * x**2 / rnanotube**2 lt rgb "blue" dashtype 3  title "max" , \
  # 1/Ananotube * krd_bot * x**2 / rnanotube**2 lt rgb "blue" dashtype 3 title "min" , \
  # 1/Ananotube * krd2_top * x**2 / rnanotube**2 lt rgb "magenta"  dashtype 3 title "max" , \
  # 1/Ananotube * krd2_bot * x**2 / rnanotube**2 lt rgb "magenta"  dashtype 3 title "min"
  # adding errorbars as full lines is too much visual clutter :( 
  
  # total powerdissipation of a single bearing:
  #1 * (2.0*10**-33 + 3.5*10**-33 * dkapka1 * R**2) * ksbear**1.7 / (l*reff)**0.7 * x**2 lt rgb "green" , \
  #1 * (2.0*10**-33 + 3.5*10**-33 * dkapka2 * R**2) * ksbear**1.7 / (l*reff)**0.7 * x**2 lt rgb "green" , \
  
# orange (planar sliding case) matches example values - check
# blue & magenta ones (nanotube bearings) should be correct - reviewed myself once 
# ----------------------------------------------------------------



# ------------------------------ SHUNNED

# SHUNNED add label about total number of bearings assumed (if assumed)
# add labels to the plotlines – dkapka values (name dominant factor) - smaller other placed legend
# add circle marker / vertical line for proposed speeds 1mm/s and speed limit
# later additional plots how friction scales with the scale of the bearing (leaving aspect ratio constant)
# add temperatures ...
# look closer into that nanotubebearing paper ....

# Total drag losses for numbearing bearings
#plot \
#  numbearings * (2.0*10**-33+3.5*10**-33*dkapka1*R**2)*ksbear**1.7 / (l*reff)**0.7 * x**2 lt rgb maincolor , \
#  numbearings * (2.0*10**-33+3.5*10**-33*dkapka2*R**2)*ksbear**1.7 / (l*reff)**0.7 * x**2 lt rgb "yellow" , \
#  numbearings * krd * x**2 / rnanotube**2 lt rgb "blue" 
# ??? last one is quite high despite bein a smaller bearing

# drag losses per bearing area -- calculating backwards to to planar area (not good)
# plot \
#  1/Abearing * (2.0*10**-33+3.5*10**-33*dkapka1*R**2)*ksbear**1.7 / (l*reff)**0.7 * x**2 lt rgb maincolor , \
#  1/Abearing * (2.0*10**-33+3.5*10**-33*dkapka2*R**2)*ksbear**1.7 / (l*reff)**0.7 * x**2 lt rgb "yellow" , \
#  1/Ananotube * krd * x**2 / rnanotube**2 lt rgb "blue"

# Ø ⌀